#Get f0 value at marked tones in TextGrid
#
#This script retrieves the f0 values of each tone labeled in a TextGrid
#and puts them in the info window preceded by the name of the word and
#syllables where they are located, as well as the label they were given.
#
#In this script, tier 6 is the point tier containing the tonal labels,
#tier 1 is the interval tier containing the syllables,
#and tier 2 is the interval tier containing the words.
#
#You must have already created a Pitch object from your Sound object.
#The Sound, TextGrid, and Pitch objects must be available in the 
#objects window.
#
#Created by Jessica Sertling Miller - sertling@uiuc.edu
#November 8, 2005
###########################################################################

select all
numberOfObjects = numberOfSelected ("Sound")
name$ = selected$ ("Sound")
numberOfPitch = numberOfSelected ("Pitch")
pitch$ = selected$ ("Pitch")
numberOfGrids = numberOfSelected ("TextGrid")
grid$ = selected$ ("TextGrid")
select TextGrid 'grid$'

clearinfo
np6 = Get number of points... 6
for i to np6

select all
select TextGrid 'grid$'
	
	toneTime = Get time of point... 6 i
	toneLabel$ = Get label of point... 6 i
	interval = Get interval at time... 1 toneTime
	sylLabel$ = Get label of interval... 1 interval
	word = Get interval at time... 2 toneTime
	wordLabel$ = Get label of interval... 2 word  

select all
pitch$ = selected$ ("Pitch")
select Pitch 'pitch$'

	f0value = Get value at time... toneTime Hertz Linear
	printline 'wordLabel$'	'sylLabel$'	'toneLabel$'	'f0value:0'

endfor